119 lines
3.5 KiB
C++
119 lines
3.5 KiB
C++
/*
|
|
RadioLib STM32WLx Blocking Transmit Example
|
|
|
|
This example transmits packets using STM32WL MCU with integrated
|
|
(SX126x) LoRa radio.
|
|
|
|
Each packet contains up to 256 bytes of data, in the form of:
|
|
- Arduino String
|
|
- null-terminated char array (C-string)
|
|
- arbitrary binary data (byte array)
|
|
|
|
This example assumes Nucleo WL55JC1 is used. For other Nucleo boards
|
|
or standalone STM32WL, some configuration such as TCXO voltage and
|
|
RF switch control may have to be adjusted.
|
|
|
|
Using blocking transmit is not recommended, as it will lead
|
|
to inefficient use of processor time!
|
|
Instead, interrupt transmit is recommended.
|
|
|
|
For default module settings, see the wiki page
|
|
https://github.com/jgromes/RadioLib/wiki/Default-configuration#sx126x---lora-modem
|
|
|
|
For full API reference, see the GitHub Pages
|
|
https://jgromes.github.io/RadioLib/
|
|
*/
|
|
|
|
// include the library
|
|
#include <RadioLib.h>
|
|
|
|
// no need to configure pins, signals are routed to the radio internally
|
|
STM32WLx radio = new STM32WLx_Module();
|
|
|
|
// set RF switch configuration for Nucleo WL55JC1
|
|
// NOTE: other boards may be different!
|
|
// Some boards may not have either LP or HP.
|
|
// For those, do not set the LP/HP entry in the table.
|
|
static const uint32_t rfswitch_pins[] =
|
|
{PC3, PC4, PC5, RADIOLIB_NC, RADIOLIB_NC};
|
|
static const Module::RfSwitchMode_t rfswitch_table[] = {
|
|
{STM32WLx::MODE_IDLE, {LOW, LOW, LOW}},
|
|
{STM32WLx::MODE_RX, {HIGH, HIGH, LOW}},
|
|
{STM32WLx::MODE_TX_LP, {HIGH, HIGH, HIGH}},
|
|
{STM32WLx::MODE_TX_HP, {HIGH, LOW, HIGH}},
|
|
END_OF_MODE_TABLE,
|
|
};
|
|
|
|
void setup() {
|
|
Serial.begin(9600);
|
|
|
|
// set RF switch control configuration
|
|
// this has to be done prior to calling begin()
|
|
radio.setRfSwitchTable(rfswitch_pins, rfswitch_table);
|
|
|
|
// initialize STM32WL with default settings, except frequency
|
|
Serial.print(F("[STM32WL] Initializing ... "));
|
|
int state = radio.begin(868.0);
|
|
if (state == RADIOLIB_ERR_NONE) {
|
|
Serial.println(F("success!"));
|
|
} else {
|
|
Serial.print(F("failed, code "));
|
|
Serial.println(state);
|
|
while (true) { delay(10); }
|
|
}
|
|
|
|
// set appropriate TCXO voltage for Nucleo WL55JC1
|
|
state = radio.setTCXO(1.7);
|
|
if (state == RADIOLIB_ERR_NONE) {
|
|
Serial.println(F("success!"));
|
|
} else {
|
|
Serial.print(F("failed, code "));
|
|
Serial.println(state);
|
|
while (true) { delay(10); }
|
|
}
|
|
}
|
|
|
|
// counter to keep track of transmitted packets
|
|
int count = 0;
|
|
|
|
void loop() {
|
|
Serial.print(F("[STM32WL] Transmitting packet ... "));
|
|
|
|
// you can transmit C-string or Arduino string up to
|
|
// 256 characters long
|
|
String str = "Hello World! #" + String(count++);
|
|
int state = radio.transmit(str);
|
|
|
|
// you can also transmit byte array up to 256 bytes long
|
|
/*
|
|
byte byteArr[] = {0x01, 0x23, 0x45, 0x56, 0x78, 0xAB, 0xCD, 0xEF};
|
|
int state = radio.transmit(byteArr, 8);
|
|
*/
|
|
|
|
if (state == RADIOLIB_ERR_NONE) {
|
|
// the packet was successfully transmitted
|
|
Serial.println(F("success!"));
|
|
|
|
// print measured data rate
|
|
Serial.print(F("[STM32WL] Datarate:\t"));
|
|
Serial.print(radio.getDataRate());
|
|
Serial.println(F(" bps"));
|
|
|
|
} else if (state == RADIOLIB_ERR_PACKET_TOO_LONG) {
|
|
// the supplied packet was longer than 256 bytes
|
|
Serial.println(F("too long!"));
|
|
|
|
} else if (state == RADIOLIB_ERR_TX_TIMEOUT) {
|
|
// timeout occured while transmitting packet
|
|
Serial.println(F("timeout!"));
|
|
|
|
} else {
|
|
// some other error occurred
|
|
Serial.print(F("failed, code "));
|
|
Serial.println(state);
|
|
|
|
}
|
|
|
|
// wait for a second before transmitting again
|
|
delay(1000);
|
|
}
|