107 lines
2.8 KiB
C++
107 lines
2.8 KiB
C++
/*
|
|
RadioLib SX128x Blocking Transmit Example
|
|
|
|
This example transmits packets using SX1280 LoRa radio module.
|
|
Each packet contains up to 256 bytes of data, in the form of:
|
|
- Arduino String
|
|
- null-terminated char array (C-string)
|
|
- arbitrary binary data (byte array)
|
|
|
|
Other modules from SX128x family can also be used.
|
|
|
|
Using blocking transmit is not recommended, as it will lead
|
|
to inefficient use of processor time!
|
|
Instead, interrupt transmit is recommended.
|
|
|
|
For default module settings, see the wiki page
|
|
https://github.com/jgromes/RadioLib/wiki/Default-configuration#sx128x---lora-modem
|
|
|
|
For full API reference, see the GitHub Pages
|
|
https://jgromes.github.io/RadioLib/
|
|
*/
|
|
|
|
// include the library
|
|
#include <RadioLib.h>
|
|
|
|
// SX1280 has the following connections:
|
|
// NSS pin: 10
|
|
// DIO1 pin: 2
|
|
// NRST pin: 3
|
|
// BUSY pin: 9
|
|
SX1280 radio = new Module(10, 2, 3, 9);
|
|
|
|
// or detect the pinout automatically using RadioBoards
|
|
// https://github.com/radiolib-org/RadioBoards
|
|
/*
|
|
#define RADIO_BOARD_AUTO
|
|
#include <RadioBoards.h>
|
|
Radio radio = new RadioModule();
|
|
*/
|
|
|
|
void setup() {
|
|
Serial.begin(9600);
|
|
|
|
// initialize SX1280 with default settings
|
|
Serial.print(F("[SX1280] Initializing ... "));
|
|
// carrier frequency: 2400.0 MHz
|
|
// bandwidth: 812.5 kHz
|
|
// spreading factor: 9
|
|
// coding rate: 7
|
|
// output power: 10 dBm
|
|
// preamble length: 12 symbols
|
|
// CRC: enabled
|
|
int state = radio.begin();
|
|
if (state == RADIOLIB_ERR_NONE) {
|
|
Serial.println(F("success!"));
|
|
} else {
|
|
Serial.print(F("failed, code "));
|
|
Serial.println(state);
|
|
while (true) { delay(10); }
|
|
}
|
|
|
|
// some modules have an external RF switch
|
|
// controlled via two pins (RX enable, TX enable)
|
|
// to enable automatic control of the switch,
|
|
// call the following method
|
|
// RX enable: 4
|
|
// TX enable: 5
|
|
/*
|
|
radio.setRfSwitchPins(4, 5);
|
|
*/
|
|
}
|
|
|
|
// counter to keep track of transmitted packets
|
|
int count = 0;
|
|
|
|
void loop() {
|
|
Serial.print(F("[SX1280] Transmitting packet ... "));
|
|
|
|
// you can transmit C-string or Arduino string up to
|
|
// 256 characters long
|
|
String str = "Hello World! #" + String(count++);
|
|
int state = radio.transmit(str);
|
|
|
|
// you can also transmit byte array up to 256 bytes long
|
|
/*
|
|
byte byteArr[] = {0x01, 0x23, 0x45, 0x56, 0x78, 0xAB, 0xCD, 0xEF};
|
|
int state = radio.transmit(byteArr, 8);
|
|
*/
|
|
|
|
if (state == RADIOLIB_ERR_NONE) {
|
|
// the packet was successfully transmitted
|
|
Serial.println(F("success!"));
|
|
|
|
} else if (state == RADIOLIB_ERR_PACKET_TOO_LONG) {
|
|
// the supplied packet was longer than 256 bytes
|
|
Serial.println(F("too long!"));
|
|
|
|
} else {
|
|
// some other error occurred
|
|
Serial.print(F("failed, code "));
|
|
Serial.println(state);
|
|
|
|
}
|
|
|
|
// wait for a second before transmitting again
|
|
delay(1000);
|
|
}
|